Badge problem

Presentation of the problem

1. Title: ML94/COLT94 Badge Problem

2. Source Information
   -- Creator: Haym Hirsh, after an idea by Rob Schapire
   -- Donor: Haym Hirsh (hirsh@cs.rutgers.edu)
   -- Date: September, 1994
 
3. Past Usage:
    Every pre-registered attendee at the 1994 Machine Learning
    Conference and 1994 Computational Learning Theory Conference received
    a badge labeled with a "+" or "-".  The labeling was due to some
    function known only to the badge generator (Haym Hirsh), and it
    depended only on the attendee's name.  The goal for conference
    attendees was to identify the unknown function used to generate the
    +/- labeling.

4. Relevant Information:
    Part of the problem in using an automated program to discover the
    unknown target function is to decide how to encode names such that
    the program can be used.  The data below are presented in the form
    of a +/- label followed by the person's name.  It is up to the
    learning-system user to decide how to convert this data into something
    usable by the system (e.g., what attributes to use if your favorite
    learner requires feature-vector data).

• as plain text: badges.data
• as ARFF file badges_plain.arff (the file format often used in Weka)

My solution

#!/usr/bin/perl -w
# 
# Sun Oct 14 08:55:57 2001/hakank@bonetmail.com
# 
# Generate attributes for the badges problem
# 
$|=1;
use strict;

my $file = "badges.data";

open FILE, $file or die "Cannot open $file: $!";

my %data = ();
while (<FILE>) {
  next if /^\s*$/;
  chomp;
  $data{$2} = $1 if m/([+-])\s+(.+)$/;
}

my @names = join ",", map {"\"$_\""} sort keys %data;

print<<EOF;
\@relation badges
\@attribute name {@names}
\@attribute length numeric
\@attribute even_odd {0,1}
\@attribute first_char_vowel {0,1}
\@attribute second_char_vowel {0,1}
\@attribute vowels numeric
\@attribute consonants numeric
\@attribute vowel_consonant_ratio numeric
\@attribute spaces numeric
\@attribute dots numeric
\@attribute words numeric
\@attribute class {-,+}
\@data
EOF

foreach my $name (sort keys %data) {
  my @name              = split //, $name;

  my $length            = length $name;
  my $even_odd_len      = ($length % 2 == 0) ? 1 : 0;
  my ($vowels, $consonants, $spaces, $ratio, $dots)
                        = vowels_consonants_spaces($name);
  my $first_char_vowel  = (is_vowel($name[0]) == 1) ? 1 : 0;
  my $second_char_vowel = (is_vowel($name[1]) == 1) ? 1 : 0;
  my @words             = split /\s+/, $name;
  my $words             = scalar @words;

  print "\"$name\", $length, $even_odd_len, $first_char_vowel, $second_char_vowel, $vowels, $consonants, $ratio, $spaces, $dots, $words, $data{$name}\n";
}


sub is_vowel {
  my ($char) = @_;

  return 1 if lc $char =~ /^[aeiou]$/i;

  return 0;
}


sub vowels_consonants_spaces {
  my ($name)     = @_;

  my $vowels     = 0;
  my $consonants = 0;
  my $spaces     = 0;
  my $dots       = 0;

  for (split //, $name) {
    $_ = lc $_;
    if (/[aeiou]/i)     {
      $vowels++;
    } elsif ($_ eq " ") {
      $spaces++;
    } elsif ($_ eq ".") {
      $dots++;
    } else              {
      $consonants++
    }

  }

  my $ratio = sprintf "%0.2f", $vowels/$consonants;
  return ($vowels, $consonants, $spaces, $ratio, $dots);

}

java weka.classifiers.trees.j48.J48 -t badges2.arff

J48 pruned tree
---------------

second_char_vowel = 0: - (84.0)
second_char_vowel = 1: + (210.0)

....
=== Error on training data ===

Correctly Classified Instances         294              100      %
.....

=== Confusion Matrix ===

   a   b   <-- classified as
  84   0 |   a = -
   0 210 |   b = +
....

Final note